cmake_minimum_required(VERSION 3.3)
project(libdi-php)

set(PROJECT_BRIEF "DI-Net PHP library (libdi-php)")

# CMake configuration
if (CMAKE_BUILD_TYPE STREQUAL "Debug")
	include("common/cmake/MemCheck.txt")
	include(CTest)
endif()
include(ExternalProject)

set(PRIMARY_LANGUAGE "C")

set(CPACK_DEBIAN_PACKAGE_DEPENDS "php7.1-cli (>= 7.1)")
include("common/cmake/CMakeLists.txt")

find_package(Libdi COMPONENTS can REQUIRED)
find_package(PHP REQUIRED)

include_directories(SYSTEM
	${PHP_INCLUDE_DIRS}
	${Libdi_INCLUDE_DIRS}
)

include_directories(
	"${PROJECT_SOURCE_DIR}/include"
	"${PROJECT_BINARY_DIR}/include"
)

set(LIBDI_PHP_SRC
	"src/extension.cpp"
	"src/constants.cpp"
	"src/socketcan.cpp"
	"src/can.cpp"
	"src/can_send.cpp"
	"src/can_send_periodic.cpp"
)

foreach(f ${LIBDI_PHP_SRC})
	# -Wno-old-style-cast -> Ignore old style warnings because we actual test C
	# -Wunused-parameter  -> Because PHP is odd and Zend writen in C
	#  error: ISO C++11 does not allow conversion from string literal to 'char *' [-Werror,-Wwritable-strings]
	set_source_files_properties(${f} PROPERTIES COMPILE_FLAGS "-Wno-old-style-cast -Wno-unused-parameter -Wno-writable-strings")
endforeach()

add_library(${PROJECT_NAME} SHARED ${LIBDI_PHP_SRC})
add_dependencies(${PROJECT_NAME} ${Libdi_LIBRARY})
set_target_properties(${PROJECT_NAME} PROPERTIES OUTPUT_NAME "di") # Rewrite libdi-php output name to di
set_target_properties(${PROJECT_NAME} PROPERTIES PREFIX "")      # Remove "lib" prefix from libdi.so
target_link_libraries(${PROJECT_NAME} ${Libdi_LIBRARY})

# Install/package
install(TARGETS ${PROJECT_NAME} DESTINATION ${PHP_EXTENSIONS_DIR})
install(PROGRAMS bin/di-candump DESTINATION usr/bin)
install(PROGRAMS bin/di-can-fakedevice DESTINATION usr/bin)
install(PROGRAMS bin/di-can-setbaudrate DESTINATION usr/bin)

if (BUILD_TESTING)
	enable_linting()
endif()

add_subdirectory(tests)
add_subdirectory(etc)